Xwork's Blog

EL día de hoy vamos a continuar con la creación de instalador en NSIS. En post anteriores, ya hemos visto alguna cosas útiles para incluirlas en el instalador. Para continuar  y hacer un instalador lo más presentable posible, veremos algunas cosas más que ayudaran a crear un buen instalador.

Tip #2 - Apéndice de todos los valores posibles para el des-instalador.

Para agregar una entrada del tipo REG_SZ o DWORD usando NSIS usaremos las siguientes instrucciones:

WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "HelpLink" "http://xworkforall.blogspot.com/2016/07/el-video-correcto-2.html"
WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "NoModify" 1

La instrucción WriteRegStr es las que se usará cuando se quieran escribir valores REG_SZ (normalmente cadenas de texto) y la instrucción WriteRegDWORD, escribirá los valores DWORD (números por lo general).


Ahora supongamos que queremos agregar un comentario al instalador que usamos cómo ejemplo (antes de continuar, si no has visto el código fuente del instalador de VEncoder 2 sugiero que lo descargues y le eches un vistazo). Para agregar los comentarios, necesitamos escribir un valor en el registro, retomado el código anterior , solo hay que usar la función que escribe un valor REG_SZ y escribir un valor llamado "Comments" y su contenido será el texto que queremos mostrar.

WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "HelpLink" "http://xworkforall.blogspot.com/2016/07/el-video-correcto-2.html"
WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "NoModify" 1
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "Comments" "Eres libre se usarlo y modificarloa tu gusto, pero no reclamarlo cómo tuyo"

Tras re-compilar el instalador y ejecutarlo, al buscar la información en el registro lucirá cómo se ve en la siguiente imagen:

Tip #3 - Asociando una extensión a nuestro programa.

Otra parte de nuestro instalador, es la posibilidad de que ciertos tipos de archivo se abran con nuestro programa. NSIS ayuda a hacer esta tarea de forma sencilla.


Retomando el ejemplo que se incluye en la descarga, al compilarlo y ejecutarlo, verás que todos los archivos con extensión VEPX, cambian y en lugar de aparecer el icono de archivo desconocido, aparece uno como el de la imagen anterior. Si hacemos doble clic en el archivo, se abrirá un cuadro de dialogo preguntándonos que programa queremos usar para abrir ese tipo de archivos.
Normalmente, queremos que cuando el usuario haga clic en ellos, se abra nuestro programa y a partir de ahi, trabajaremos con este archivo.
Para poder abrir directamente el archivo con nuestro programa, debemos de crear entradas en el registro de Windows.

HKEY_CLASSES_ROOT
   MyProgram.exe
      shell
         open
            command
               (Default) = C:\MyDir\MyProgram.exe /a "%1"
         print
            command
               (Default) = C:\MyDir\MyProgram.exe /a /p "%1"
         printto
            command
               (Default) = C:\MyDir\MyProgram.exe /a /p "%1" "%2"

El código anterior muestra cómo se deben de crear las entradas en el registro de windows.
Para eso vamos a agregar el siguiente código en NSIS:

WriteRegStr HKCR ".VEPX" "" "VEncoder.VEPX"
WriteRegStr HKCR "VEncoder.VEPX" "" "Archivo de perfil para Vencoder"
WriteRegStr HKCR "Vencoder.VEPX\DefaultIcon" "" "$INSTDIR\VEPX.ico" 
WriteRegStr HKCR "VEncoder.VEPX\shell\Open\" "" "Cargar en VEncoder 2"
WriteRegStr HKCR "VEncoder.VEPX\shell\Open\command" "" "$INSTDIR\Vencoder 2.exe"

Hola de nuevo a todos, el día de hoy vamos a continuar con el tema de los instaladores, en el post anterior vimos lo básico de como escribir el código en NSIS. Hoy veremos unas cuantas cosas que nos ayudaran a hacer un instalador más detallado.

Tip #1 - El Desintalador.

Si observamos bien, vemos que hay una entrada a nuestro des-instalador, pero no sabemos nada más.

Este es un ejeplo de un programa que muestra información que puede ser de ayuda para el usuario.

WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Vencoder" "DisplayName" "Vencoder 2.0"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "UninstallString" '"$INSTDIR\uninstall.exe"'
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "Publisher" "MDev 2015"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "DisplayIcon" "$INSTDIR\Main.ico"
${GetSize} "$INSTDIR" "/M=*.* /S=0K " $0 $1 $2
WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "EstimatedSize" "$0"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "DisplayVersion" "2.1" 
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "URLInfoAbout" "http://xworkforall.blogspot.com"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "HelpLink" "http://xworkforall.blogspot.com/2016/07/el-video-correcto-2.html"
WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "NoModify" 1
WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VEncoder" "NoRepair" 1

Las lineas de código scriben entradas en el registro de Windows la instruccion "WriteRegStr" escribe un valor de cadena (texto por lo general), la instruccion WriteRegDWORD, escribe un valor DWORD.
En orden de aparicion, las lineas del código anterior se usan para representar la siguiente información:

1. Nombre que se mostrara en la entrada al des-instalador.
2. Ruta en la que se encuentra el des-instalador, siempre debe de ir entre comillas.
3. Información del publicador (empresa).
4. Icono que se usara para mostrarse en la lista de programas.
5. ${GetSize} Es una función de NSIS que se usa para obtener el tamaño de un folder o archivo. Está la veremos con mayor detalle un poco más adelante, pero en este caso se usa para obtener el tamaño de la instalación. Para que funcione es importante que previamente ya se hayan copiado todos los archivos a la carpeta de instalación.
6. Cuando ya obtuvimos el tamaño de la instalación; está función escribe esa información. Para que funcione, el tamaño debe de estar en KiloBytes.
7. Muestra la versión del programa.
8. Vinculo a una dirección de internet "Acerca de".
9. Vinculo a una dirección con ayuda para el programa.
10. Cuando NO se tiene la opcion de modificar los componente ya instalados.
11. Cuando NO se tiene la opcion de reparar la instalacion.

Para que des-instalador funcione, minimamente se deben de escribir las entradas "DisplayName" y "UninstallString", de ahí en fuera las otras son totalmente opcionales, pero siempre es recomendable incluir al menos todas las anteriores para tener el mínimo de información necesaria.

Al escribir todas las entradas anteriores, cuando vayamos a la seccion de des-instalar programas, nuestra aplicación tendrá el siguiente aspecto:

Y bien, es todo por hoy, en el siguiente post veremos cómo asociar una extensión con nuestro programa, recuerda que el código de este post lo puedes bajar de mi dropbox, viene con un ejemplo de un instalador para VEncoder 2.

P.D Hay que adaptar el código de VEncoder para funcionar desde "Program Files", ya que cuando se usa desde está ruta, requiere  de algunos cambios.

Los leo luego.

Hola de nuevo a todos, el día de hoy les voy a mostrar el código detrás de un instalador que hice ya hace tiempo.
Cómo muchos de ustedes sabrán. Yo soy programador y he hecho programas de muchos tipos, algunos más complejos que otros. Dependiendo del grado de complejidad muchos de ellos vienen divididos, es decir; algunas funciones criticas las hago en bibliotecas DLL y al momento de distribuir el programa, cuando llega al usuario final, en ocasiones los usuarios "pierden alguna" DLL o algún recurso que el programa necesita. Inicialmente solo empaquetaba todo en un archivo ZIP y en el programa principal, programaba que hiciera los cambios en el sistema que fueran necesarios para que tdo funcionara correctamente, además siempre incluía un manual de ayuda (que al parecer nadie leía) para que el usuario pudiera arreglar los problemas comunes.
Pero cómo siempre aparecían errores decidí buscar una manera de minimizarlos lo más posible. Para eso busque la forma de hacer un instalador, y poder distribuir todo lo necesario en un solo paquete y además hacer los ajustes necesarios para que el usuario solo ejecutará la aplicación y evitar disgustos.

Al inicio probé con una herramienta que se llama Create Install Free, al inicio era gratuita, funcionaba de maravilla, permitía agregar y registrar bibliotecas en windows, fuentes y controles OCX, era una solución muy buena. Tiempo después paso a tener costo, y me hubiera gustado comprarlo, pero no tenía una tarjeta de crédito valida para realizar la compra. Entonces dejé de usarlo y busqué otra forma de crear un paquete de instalación.

Así fue cómo llegué a NSIS.

Nullsoft Scriptable Install System (NSIS) es un "manejador de script" Windows de código abierto con requerimientos mínimos, desarrollado por Nullsoft, los creadores de Winamp. NSIS ha crecido en popularidad como una alternativa al uso extenso de productos comerciales como InstallShield y es actualmente utilizado para un sin número de aplicaciones distribuidas a través de Internet.
NSIS es liberado bajo una combinación de licencias de software libre, principalmente la licencia de zlib/libpng, de esta forma haciendo a NSIS software libre..

Creando un instalador.

Una vez que tenemos todo listo vamos a empezar a escribir el código. Tomemos está parte de código y revisemos cada una de las partes que lo componen.

!include "MUI2.nsh"
!include "FileFunc.nsh"
!include "Library.nsh"

SetCompressor lzma
SetOverwrite on
SetDatablockOptimize on
!define VERSION "2.0"
Name "VEncoder 2"

OutFile "Setup.exe"
InstallDir "$PROGRAMFILES\Vencoder 2"
InstallDirRegKey HKCU "Software\MPM\VENCODER 2" ""
ShowInstDetails show
RequestExecutionLevel admin
CRCCheck on
XPStyle on

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "COPYING.txt"
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_WELCOME
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_LANGUAGE "Spanish"

MUI_PAGE_LICENSE "COPYING.txt": Crea la página que muestra un archivo de texto llamado "Copying.txt" cómo licencia, se puede usar cualquier fichero de texto y asignarlo cómo parámetro.

MUI_PAGE_COMPONENTS: Muestra una página que permite seleccionar que secciones son las que queremos instalar.

MUI_PAGE_DIRECTORY: Muestra la página que nos permite la selección de un folder para llevar a cabo la instalación.

MUI_PAGE_INSTFILES: Muestra el progreso de la instalacion.

MUI_PAGE_FINISH: Muestra un mensaje al finalizar la instalación.

Para este caso tenemos tres secciones, 2 de ellas obligatorias y una de ellas opcional.

Section "Principal" MainSec
##Indicamos que está seccion es obligatoria
SectionIn RO
##Establecemos la carpeta de destino
SetOutPath "$INSTDIR"
File "Copying.txt"
File "Main.Ico"
File "MediaInfo.dll"
File "MediaInfoNET.dll"
File "Vencoder 2.exe"
File "Vepx.ico"
File "ListViewEx.dll"
SetOutPath $INSTDIR\Doc
File /r doc\*.*
SectionEnd

Section "Archivos adicionales" AdditionalSec
SetOutPath "$DOCUMENTS\Profiles"
File "MB300.Vepx"
File "PSP.vepx"
File "PSVita.vepx"
File "Screen HD.Vepx"
File "Screen FHD.Vepx"
SectionEnd

Con el código previo, definimos dos secciones, cada "section" recibe 2 parámetros, uno de ellos es una descripción y el otro es un nombre que servirá para identificar cada una de las secciones.
Para la primera sección indicamos que es obligatoria con "SectionIn RO" cuando se establece, en la página de selección de componentes, aparecerá un casilla de selección de solo de lectura, cuando no se incluye, el usuario puede marcar o des-marcar la casilla de selección, así indicando que esa sección no se quiere instalar.
En la seccion "MainSec", después de que establecimos que sea obligatoria, agregamos todos los archivos necesarios de nuestra aplicación, primero establecemos que todos se copiaran a la carpeta de instalacion "$INSTDIR" ("C:\Program Files (x86)\VENcoder2\"), luego ponemos una lista en la que cada archivo inicia con la palabra clave "File" seguida por el nombre del archivo que queremos incluir, un poco más abajo encontramos la instrucción "SetOutPath" nuevamente con la ruta "$INSTDIR\Doc", esto indica que se debe de cambiar la salida de los archivo a está nueva dirección, luego al comando "File" le agregamos el parámetro "\r" que indica que buscara de forma recursiva lo archivos en la carpeta doc.

Cada seccion debe de incluir una descripcion, para definirlas, se usa código similar al siguiente:

!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
!insertmacro MUI_DESCRIPTION_TEXT ${MainSec} "Contiene todos los archivos escenciales de la aplicacion"
!insertmacro MUI_DESCRIPTION_TEXT ${LinkSec} "Accesos directos a la aplicacion)"
!insertmacro MUI_DESCRIPTION_TEXT ${AdditionalSec} "Archivos de perfil con las configuraciones mas frecuentes (opcional)"
!insertmacro MUI_FUNCTION_DESCRIPTION_END

Despues llamamos a las macros que se encarhgan de crear las descripciones; MUI_FUNCTION_DESCRIPTION_BEGIN, recibe dos parámetros, uno de ellos es el nombre de la seccion a la cual se quiere poner su descripción y el segundo, es la cadena de texto.

Lo que se mostró en el post son las partes principales, pero el código completo junto con lo archivos, como siempre; lo dejo en mi dropbox para que lo descargues y lo revises. Incluye todo lo necesario para crear un instalador funcional para VEncoder.
En el siguiente Post vamos a ver alguna funciones no vitales, pero que resultan muy útiles.

Por ahora es todo, los leo luego